メニューを作成します。
#Include <GuiMenu.au3>
_GUICtrlMenu_CreateMenu([$iStyle = 8])
パラメータ
| $iStyle | [オプション]メニューのスタイル。次の値の1つまたは複数です: 1 - マウスがメニューの外側に10秒間出るとメニューは自動的に終了します 2 - チェックマーク用とビットマップ用に同じスペースが確保されます 4 - メニューアイテムをOLEドロップターゲットまたはドラッグソースにします 8 - メニューをモーダレスにします 16 - アイテムの左側にチェックマーク用のスペースを確保しません 32 - 選択がおこなわれた際にメニューのオーナーは$WM_COMMANDメッセージの代わりに$WM_MENUCOMMANDメッセージを受け取ります |
返し値
| 成功: | 新しく作成されたメニューのハンドル |
| 失敗: | 0 |
注意
ウィンドウに割り当てられたメニューのリソースは自動的に解放されます。
関連
_GUICtrlMenu_CreatePopup, _GUICtrlMenu_DestroyMenu
こちらも参照
MSDNライブラリでCreateMenuを検索して下さい。
例
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
Global Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
; GUIを作成
$hGUI = GUICreate("Menu", 400, 300)
; ファイルメニューを作成
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)
; 編集メニューを作成
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)
; ヘルプメニューを作成
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)
; メインメニューを作成
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)
; ウィンドウにメニューを設定
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; ユーザーが終了するまでループ
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メニューコマンドを制御
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
Switch _WinAPI_LoWord ($iwParam)
Case $idNew
MemoWrite("New")
Case $idOpen
MemoWrite("Open")
Case $idSave
MemoWrite("Save")
Case $idExit
Exit
Case $idCut
MemoWrite("Cut")
Case $idCopy
MemoWrite("Copy")
Case $idPaste
MemoWrite("Paste")
Case $idAbout
MemoWrite("About")
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite