指定されたウィンドウのメニューバーを再描画します。
#Include <GuiMenu.au3>
_GUICtrlMenu_DrawMenuBar($hWnd)
パラメータ
| $hWnd | 再描画が必要なメニューバーを持つウィンドウのハンドル |
返し値
| 成功: | True |
| 失敗: | False |
注意
Windowsがウィンドウを作成した後にメニューバーが変更された場合、メニューバーを描画するためにこの関数を呼ぶ必要があります。
関連
こちらも参照
MSDNライブラリでDrawMenuBarを検索して下さい。
例
#include <GuiMenu.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hWnd, $hMain, $hItem1, $hItem2
; メモ帳を開く
Run("Notepad.exe")
WinWaitActive("[CLASS:Notepad]")
$hWnd = WinGetHandle("[CLASS:Notepad]")
$hMain = _GUICtrlMenu_GetMenu($hWnd)
; サブアイテムメニューを作成
$hItem1 = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hItem1, 0, "SubItem &1", 0x1000)
_GUICtrlMenu_InsertMenuItem($hItem1, 1, "SubItem &2", 0x1001)
; メニューを作成
$hItem2 = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hItem2, 0, "Item &1", 0x2000, $hItem1)
_GUICtrlMenu_InsertMenuItem($hItem2, 1, "Item &2", 0x2001)
_GUICtrlMenu_InsertMenuItem($hItem2, 2, "", 0)
_GUICtrlMenu_InsertMenuItem($hItem2, 3, "Item &3", 0x2002)
_GUICtrlMenu_InsertMenuItem($hItem2, 4, "Item &4", 0x2003)
; メモ帳に新しいメニューを挿入
_GUICtrlMenu_InsertMenuItem($hMain, 6, "&AutoIt", 0, $hItem2)
_GUICtrlMenu_DrawMenuBar($hWnd)
EndFunc ;==>_Main