アイテムテキストに基づいてメニューアイテムを取得します。
#Include <GuiMenu.au3>
_GUICtrlMenu_FindItem($hMenu, $sText[, $fInStr = False[, $iStart = 0]])
パラメータ
| $hMenu | メニューハンドル |
| $sText | 検索テキスト |
| $fInStr | [オプション]Trueの場合、テキストはアイテムテキストの任意位置のテキストです。 |
| $iStart | [オプション]検索開始位置のアイテム |
返し値
| 成功: | テキストを含む最初のアイテムのゼロ始まりのインデックス |
| 失敗: | -1 |
注意
検索では大文字小文字は区別されません。
関連
例
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $iIndex
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; GUIを作成
$hGUI = GUICreate("Menu", 400, 300)
GUISetState()
; ファイルメニューを作成
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)
; 編集メニューを作成
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)
; ヘルプメニューを作成
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)
; メインメニューを作成
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)
; ウィンドウにメニューを設定
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; ヘルプのメニューアイテムをクリック
$iIndex = _GUICtrlMenu_FindItem ($hMain, "Help")
MsgBox(4096, "Information", "Index for Help Menu: " & $iIndex)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main