指定されたアイテムによってアクティブ化されるサブメニューを取得します。
#Include <GuiMenu.au3>
_GUICtrlMenu_GetItemSubMenu($hMenu, $iItem)
パラメータ
| $hMenu | メニューのハンドル |
| $iItem | メニューアイテムのゼロ始まりの位置 |
返し値
| 成功: | そのメニューアイテムによって開かれるドロップダウンメニューまたはサブメニューのハンドル |
| 失敗: | 0 |
注意
なし。
関連
_GUICtrlMenu_SetItemSubMenu, _GUICtrlMenu_RemoveMenu
こちらも参照
MSDNライブラリでGetSubMenuを検索して下さい。
例
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; GUIを作成
$hGUI = GUICreate("Menu", 400, 300)
; ファイルメニューを作成
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)
; 編集メニューを作成
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)
; ヘルプメニューを作成
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)
; メインメニューを作成
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, 0)
; ウィンドウにメニューを設定
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; ヘルプメニューを取得/設定
MemoWrite("Help submenu handle: " & _GUICtrlMenu_GetItemSubMenu ($hMain, 2))
_GUICtrlMenu_SetItemSubMenu ($hMain, 2, $hHelp)
MemoWrite("Help submenu handle: " & _GUICtrlMenu_GetItemSubMenu ($hMain, 2))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite