コントロール表示の下限を表す日付け情報を取得します。
#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthRangeMin($hWnd[, $fPartial = False])
パラメータ
| $hWnd | コントロールのハンドル |
| $fPartial | [オプション]取得される範囲のスコープを指定します: True - 前月と来月を含めます False - 全体が表示されている月のみ含めます |
返し値
成功: $tagSYSTEMTIME構造体
注意
なし。
関連
_GUICtrlMonthCal_GetMonthRange, _GUICtrlMonthCal_GetMonthRangeMax, _GUICtrlMonthCal_GetMonthRangeMinStr, $tagSYSTEMTIME
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_MC = False ; MonthCal関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $tMin, $tMax, $hMonthCal
; GUIを作成
GUICreate("Month Calendar Get Month Range Min", 400, 300)
$hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 月の範囲を取得
$tMin = _GUICtrlMonthCal_GetMonthRangeMin($hMonthCal)
$tMax = _GUICtrlMonthCal_GetMonthRangeMax($hMonthCal)
MemoWrite("Month range minimum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMin, "Month"), _
DllStructGetData($tMin, "Day"), _
DllStructGetData($tMin, "Year")))
MemoWrite("Month range maximum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMax, "Month"), _
DllStructGetData($tMax, "Day"), _
DllStructGetData($tMax, "Year")))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite