現在の選択されている日付けを設定します。
#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCurSel($hWnd, $iYear, $iMonth, $iDay)
パラメータ
| $hWnd | コントロールのハンドル |
| $iYear | 年 |
| $iMonth | 月 |
| $iDay | 日 |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GUICtrlMonthCal_GetCurSel
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_MC = False ; MonthCal関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $tTime, $hMonthCal
; GUIを作成
GUICreate("Month Calendar Set Cur Sel", 400, 300)
$hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 現在の選択を取得/設定
_GUICtrlMonthCal_SetCurSel($hMonthCal, @YEAR, 8, 19)
$tTime = _GUICtrlMonthCal_GetCurSel($hMonthCal)
MemoWrite("Current selection : " & StringFormat("%02d/%02d/%04d", DllStructGetData($tTime, "Month"), _
DllStructGetData($tTime, "Day"), _
DllStructGetData($tTime, "Year")))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite