カレンダーコントロールの指定された日付け範囲を選択します。
#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetSelRange($hWnd, $iMinYear, $iMinMonth, $iMinDay, $iMaxYear, $iMaxMonth, $iMaxDay)
パラメータ
| $hWnd | コントロールのハンドル |
| $iMinYear | 最小年 |
| $iMinMonth | 最小月 |
| $iMinDay | 最小日 |
| $iMaxYear | 最大年 |
| $iMaxMonth | 最大月 |
| $iMaxDay | 最大日 |
返し値
| 成功: | True |
| 失敗: | False |
注意
この命令は$MCS_MULTISELECTスタイルを使用していないカレンダーコントロールに適用すると失敗します。
関連
_GUICtrlMonthCal_GetSelRange
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_MC = False ; MonthCal関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $tRange, $hMonthCal
; GUIを作成
GUICreate("Month Calendar Set Sel Range", 400, 300)
$hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 選択部を取得/設定
_GUICtrlMonthCal_SetSelRange($hMonthCal, @YEAR, @MON, 1, @YEAR, @MON, 7)
$tRange = _GUICtrlMonthCal_GetSelRange($hMonthCal)
MemoWrite("Start date: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MinMonth"), _
DllStructGetData($tRange, "MinDay"), _
DllStructGetData($tRange, "MinYear")))
MemoWrite("End date .: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MaxMonth"), _
DllStructGetData($tRange, "MaxDay"), _
DllStructGetData($tRange, "MaxYear")))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite