フラグが設定されているかを判定します。
#Include <GuiRebar.au3>
_GUICtrlRebar_GetBandStyleChildEdge($hWnd, $iIndex)
パラメータ
| $hWnd | レバーコントロールのハンドル |
| $iIndex | バンドのゼロ始まりのインデックス |
返し値
True: フラグが設定されています(バンドは子ウィンドウの上部と下部に縁を持ちます)
注意
なし。
関連
_GUICtrlRebar_SetBandStyleChildEdge, _GUICtrlRebar_GetBandStyle
例
#include <GuiConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolBar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt("MustDeclareVars", 1)
$Debug_RB = False
Global $iMemo
_Main()
Func _Main()
Local $hgui, $btnExit, $hReBar, $hToolbar, $hInput
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
$hgui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))
; レバーコントロールを作成
$hReBar = _GUICtrlReBar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))
$iMemo = GUICtrlCreateEdit("", 2, 100, 396, 250, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
; レバーに挿入するツールバーを作成
$hToolbar = _GUICtrlToolBar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))
; 標準システムビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; レバーに挿入する入力ボックスを作成
$hInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)
; コントロールを格納しているバンドを追加
_GUICtrlReBar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Name:")
; コントロールを格納しているバンドをレバーの最初に追加
_GUICtrlReBar_AddToolBarBand($hReBar, $hToolbar, "", 0)
$btnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
GUICtrlSetState($btnExit, $GUI_DEFBUTTON)
GUICtrlSetState($btnExit, $GUI_FOCUS)
GUISetState(@SW_SHOW)
_GUICtrlRebar_SetBandStyleBreak($hReBar, 1)
MsgBox(4096, "Information", "Setting Child Edge Style")
For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
_GUICtrlRebar_SetBandStyleChildEdge($hReBar, $x, False)
MemoWrite("Band Index " & $x & @TAB & "$RBBS_CHILDEDGE.....: " & _GUICtrlRebar_GetBandStyleChildEdge($hReBar, $x))
MemoWrite("============================================")
Next
MsgBox(4096, "Information", "Setting Child Edge Style")
For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
_GUICtrlRebar_SetBandStyleChildEdge($hReBar, $x)
MemoWrite("Band Index " & $x & @TAB & "$RBBS_CHILDEDGE.....: " & _GUICtrlRebar_GetBandStyleChildEdge($hReBar, $x))
MemoWrite("============================================")
Next
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $btnExit
Exit
EndSwitch
WEnd
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite