選択部のフォント属性を取得します。選択されていない場合は挿入位置のフォント属性を取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetFont($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | 値を格納した配列: |
| [0] - ポイントサイズ | |
| 選択部でサイズが複数ある場合、0 | |
| [1] - フォント名 | |
| 選択部でフォントが複数ある場合、"" | |
| [2] - 文字セット | |
| $ANSI_CHARSET - 0 | |
| $BALTIC_CHARSET - 186 | |
| $CHINESEBIG5_CHARSET - 136 | |
| $EASTEUROPE_CHARSET - 238 | |
| $GB2312_CHARSET - 134 | |
| $GREEK_CHARSET - 161 | |
| $HANGEUL_CHARSET - 129 | |
| $MAC_CHARSET - 77 | |
| $OEM_CHARSET - 255 | |
| $RUSSIAN_CHARSET - 204 | |
| $SHIFTJIS_CHARSET - 128 | |
| $SYMBOL_CHARSET - 2 | |
| $TURKISH_CHARSET - 162 | |
| $VIETNAMESE_CHARSET - 163 | |
| 失敗: | @errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
なし。
関連
_GUICtrlRichEdit_SetFont
こちらも参照
MSDNライブラリでhttp://www.hep.wisc.edu/~pinghc/books/apirefeng/l/logfont.htmlを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
Report("1. Initial")
Case 2
_GUICtrlRichEdit_SetFont($hRichEdit, 15, "Times Roman")
Report("2. Set Font")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $aRet = _GUICtrlRichEdit_GetFont($hRichEdit)
$sMsg = $sMsg & @CR & @CR & $aRet[1] & " " & $aRet[0] & " points"
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report