複数行のエディットコントロールの行数を取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineCount($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | テキストの総行数 |
| 失敗: | 0を返し、@errorを設定します: |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
テキストが存在しないコントロールは1行と見なされます。
関連
こちらも参照
MSDNライブラリでEM_GETLINECOUNTを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
GUISetState()
For $i = 2 To 10
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Line " & $i)
Next
Report("The control contains " & _GUICtrlRichEdit_GetLineCount($hRichEdit) & " lines")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
GUICtrlSetData($lblMsg, $sMsg)
EndFunc ;==>Report