選択された段落または(選択されていない場合は)現在の段落の配置を取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaAlignment($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | 値とセミコロン(;)、範囲を表す文字で構成された文字列: |
| 配置: | |
| l - 左マージンに整列 | |
| r - 右マージンに整列 | |
| c - マージン間で中央揃え | |
| j - マージンに合わせて整列 | |
| f - マージンに合わせて整列 | |
| w - 拡張スペースのみによってマージンに合わせて整列 | |
| 範囲: | |
| a - 全て(または単独の)選択された段落にこの配置が適用されています。 | |
| f - 選択された段落のうち、最初の段落のみこの配置が適用されています。 | |
| c - 現在の段落にこの配置が適用されています。 | |
| 失敗: | ""を返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
リッチエディット2.0では整列は表示されません。
関連
_GUICtrlRichEdit_SetParaAlignment
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $iCp, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "r")
Report("First paragraph")
Case 2
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "c")
Report("Second paragraph")
Case 3
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Third paragraph")
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "l")
Report("Third paragraph")
Case 4
$iCp = _GuiCtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
_GuiCtrlRichEdit_SetSel($hRichEdit, $iCp, -1)
Report("Alignment of paragraphs in selection")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaAlignment($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report