2つの指定文字の間のテキストを取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextInRange($hWnd, $iStart, $iEnd)
パラメータ
| $hWnd | コントロールのハンドル |
| $iStart | 取得したいテキストの直前の文字間位置 |
| $iEnd | 取得したいテキストの直後の文字間位置 特殊な値: -1 -テキスト終端 |
返し値
| 成功: | 目的のテキスト |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $iStartが正の数でもゼロでもありません。 | |
| 1031 - $iEndが正の数でもゼロでも-1でもありません。 | |
| 1032 - $iStart < $iEnd かつ $iEnd > -1 です |
注意
コントロール内の最初の文字の文字間位置は0です。
関連
_GUICtrlRichEdit_GetTextInLine
こちらも参照
MSDNライブラリでEM_GETTEXTRANGEを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
GUISetState()
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
_GuiCtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK)
_GuiCtrlRichEdit_AutoDetectURL($hRichEdit, True)
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
EndSelect
WEnd
EndFunc ;==>Main
Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
#forceref $hWnd, $iMsg, $iWparam
Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
$tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
$iCode = DllStructGetData($tNMHDR, "Code")
Switch $hWndFrom
Case $hRichEdit
Select
Case $iCode = $EN_LINK
$tMsgFilter = DllStructCreate($tagEN_MSGFILTER, $iLparam)
If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
$tEnLink = DllStructCreate($tagENLINK, $iLparam)
$cpMin = DllStructGetData($tEnLink, "cpMin")
$cpMax = DllStructGetData($tEnLink, "cpMax")
MsgBox(0, "", "Invoke your web browser here and point it to " & _
_GuiCtrlRichEdit_GetTextInRange($hRichEdit, $cpMin, $cpMax))
EndIf
EndSelect
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_NOTIFY