選択を非表示状態(または表示状態)にします。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_HideSelection($hWnd[, $fHide = True])
パラメータ
| $hWnd | コントロールのハンドル |
| $fHide | [オプション] True - 非表示 False - 表示 デフォルト: 非表示 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $fHideはTrueまたはFalseである必要があります。 |
注意
なし。
関連
こちらも参照
MSDNライブラリでEM_HIDESELECTIONを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_SetSel($hRichEdit, 2, 5)
Report("Text is selected")
Case 2
_GuiCtrlRichEdit_HideSelection($hRichEdit, True)
Report("Selection is hidden")
Case 3
_GuiCtrlRichEdit_HideSelection($hRichEdit, False)
Report("Selection is not hidden")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $sRet = _GuiCtrlRichEdit_GetCharAttributes($hRichEdit)
$sMsg = $sMsg & @CR & @CR & "Char Attributes=" & $sRet
GUICtrlSetData($lblMsg, $sMsg)
EndFunc ;==>Report