選択されたテキストを置換します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ReplaceText($hWnd, $sText[, $fCanUndo = True])
パラメータ
| $hWnd | コントロールのハンドル |
| $sText | 置換テキスト |
| $fCanUndo | [オプション] 操作をアンドゥできるようにするかどうか。True(デフォルト)またはFalse |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 103 - $fCanUndoはTrueまたはFalseである必要があります。 | |
| -1 - テキストが選択されていません。 |
注意
なし。
関連
_GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_SetText
こちらも参照
MSDNライブラリでEM_REPLACESELを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 5)
Case 2
_GuiCtrlRichEdit_ReplaceText($hRichEdit, "1st")
GUICtrlSetData($lblMsg, "Text has been replaced")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 3)
_GuiCtrlRichEdit_ReplaceText($hRichEdit, "")
GUICtrlSetData($lblMsg, "1st has been deleted")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main