Function Reference

_GUICtrlRichEdit_ResumeRedraw

コントロールの再描画を再開します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ResumeRedraw($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True
失敗: Falseを返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。

 

注意

なし。

 

関連

_GUICtrlRichEdit_PauseRedraw

 

こちらも参照

MSDNライブラリでWM_SETREDRAWを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
    _GUICtrlRichEdit_PauseRedraw($hRichEdit)
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GuiCtrlRichEdit_SetSel($hRichEdit, 5, 2)
                        Report("1.Redraw is paused")
                    Case 2
                        _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_2")
                        Report("2.Text is inserted at active point of selection")
                    Case 3
                        _GuiCtrlRichEdit_GotoCharPos($hRichEdit, 20)
                        _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_3")
                        Report("3.Text is inserted at insertion point and Redraw is resume")
                        _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report