指定行数分、テキストをスクロールします。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLines($hWnd, $iQlines)
パラメータ
| $hWnd | コントロールのハンドル |
| $iQlines | スクロールする行数 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $iQlinesは数値ではありません。 | |
| 700 - 1行のコントロールをスクロールしようとしました。 |
注意
下にスクロールするには$iQlinesに正の値を、上にスクロールするには負の値を設定してください。
関連
_GUICtrlRichEdit_ScrollLineOrPage, _GUICtrlRichEdit_ScrollToCaret
こちらも参照
MSDNライブラリでEM_LINESCROLLを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
For $i = 1 To 20
_GuiCtrlRichEdit_AppendText($hRichEdit,"Line " & $i & @CR)
Next
_GuiCtrlRichEdit_AppendText($hRichEdit,"Line 21")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_ScrollLines($hRichEdit, -10.2)
Report("Scrolled up")
Case 2
_GUICtrlRichEdit_ScrollLines($hRichEdit, +100)
Report("Scrolled down so only last line shows")
Case 3
_GUICtrlRichEdit_ScrollLines($hRichEdit, -200)
Report("Scrolled up all the way")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report