選択されたテキストの属性のオン・オフを切り換えます。選択されていない場合はその挿入位置に挿入されるテキストの属性が切り換えられます。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetCharAttributes($hWnd, $sStatesAndEffects [, $fWord = False])
パラメータ
| $hWnd | コントロールのハンドル |
| $sStatesAndEffects | 3文字のグループからなる文字列 : +(または-)は状態を、2文字の略語は属性を表します。 1文字目: + はオン、- はオフ 2、3文字目: 以下の通り: bo - 太字 di - 無効 - 影付きで文字を表示 [nd] em - 浮き彫り [nd] hi - 非表示、つまり表示されない im - インプリント [nd] it - 斜体 li - この属性のテキストの上にマウスがのった際にEN_LINKメッセージを送信 ou - アウトライン [nd] pr - ユーザーが変更しようとした際にEN_PROTECTメッセージを送信 re - 修正マーク [nd] sh - 影 [nd] sm - 1文字目を小文字に [nd] st - 取り消し線 sb - 下付き [nd] sp - 上付き [nd] un - 下線 |
| $fWord | [オプション] True テキストが選択されている場合、選択されているテキストのすべての語に属性を適用します。 テキストが選択されていない場合: 挿入位置が語の中、または終端にある場合、その後に属性を適用します。 もしそうでない場合、その挿入位置に挿入されたテキストに属性を適用します。 False (デフォルト) テキストが選択されている場合、選択されているテキストに属性を適用します。 テキストが選択されていない場合、その挿入位置に挿入されたテキストに属性を適用されます。 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $sStatesAndAttsの長さが3の倍数ではありません。 | |
| 1022 - グループの1文字目が + でも - でもありません。1文字目が@extendedに設定されます。 | |
| 1023 - 属性の略語が不正です。不正な略語が@extendedに設定されます。 | |
| 103 - $fWordはTrueまたはFalseである必要があります。 |
注意
属性のいくつかは表示に反映されません。反映されないのは[nd]がついているものです。
関連
_GUICtrlRichEdit_GetCharAttributes
こちらも参照
MSDNライブラリでEM_SETCHARFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "Paragraph 1 ")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
_GuiCtrlRichEdit_SetCharAttributes($hRichEdit, "+un")
Report("1. Two characters underlined")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 1, 5)
_GuiCtrlRichEdit_SetCharAttributes($hRichEdit, "+bo")
Report("2. Some characters bolded")
Case 3
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & _GUICtrlRichEdit_GetCharAttributes($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report