現在選択されている段落の属性を設定します。選択されていない場合、挿入位置に挿入される段落の属性を設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaAttributes($hWnd, $sStatesAndAtts)
パラメータ
| $hWnd | コントロールのハンドル |
| $sStatesAndAtts | セミコロン(;)で区切られたグループで構成された文字列。 各グループは次のように構成されます: 1文字目 - 状態: + - 属性をオンにします。 - - 属性をオフにします。 "fpg" - これらの段落を新しいページにする (初期設定ではオフ) "hyp" - 自動ハイフネーション (初期設定ではオン) "kpt" - これらの段落を同じページにする (初期設定ではオフ) "kpn" - これらの段落と次の段落を同じページにする (初期設定ではオフ) "pwo" - こららのパラグラフがページ上で1行になることを防ぐ (初期設定ではオフ) "r2l" - 右から左むきの順でテキストを表示する (初期設定ではオフ) "row" - 段落は表の行 (初期値はオフ) "sbs" - 段落を並べて表示 (初期設定ではオフ) "sln" - ドキュメントまたは複数行の選択部の行数を抑制する (初期設定ではオフ) |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $sStatesAndAtts内の状態を表す文字が不正です。この文字が@extendedに設定されます。 | |
| 1022 - $sStatesAndAtts内の属性を表す略語が不正です。この略語が@extendedに設定されます。 | |
| 1023 - $sStatesAndAttsの長さが不正です。 |
注意
結果はWordでは表示されますがリッチエディットでは表示されません。
関連
_GUICtrlRichEdit_GetParaAttributes
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_AppendText($hRichEdit, "First paragraph")
Report("First paragraph: default attributes")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaAttributes($hRichEdit, "-hyp")
Report("Second paragraph: hyphenation off")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, -1)
_GUICtrlRichEdit_SetParaAttributes($hRichEdit, "-hyp;+fpg;+kpn")
Report("Attributes of first paragraph in selection")
Case 3
; Wordで属性を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaAttributes($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report