現在選択されている段落の枠線を設定します。選択されていない場合、挿入位置に挿入される段落の枠線を設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaBorder($hWnd [, $sLocation [, $vLineStyle [, $sColor [, $iSpace]]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $sLocation | [オプション] 以下の論理演算結果からなる文字列: l - 左枠 r - 右枠 t - 上枠 b - 下枠 i - 内枠 o - 外枠 または "" - 枠なし(初期値) |
| $vLineStyle | [オプション] 線のスタイル - 以下のいずれか: "none" - ラインなし(初期値) .75 - 3/4ポイント 1.5 - 1 1/2ポイント 2.25 - 2 1/4ポイント 3 - 3ポイント 4.5 - 4 1/2ポイント 6 - 6ポイント ".75d" - 1/2ポイント, ダブル "1.5d" - 1 1/2ポイント, ダブル "2.25d" - 2 1/4ポイント, ダブル ".75g" - 3/4ポイント, グレー ".75gd" - 3/4ポイント, グレー, 点線 |
| $sColor | [オプション] 以下のいずれか: "aut" - 自動色 "blk" - 黒 (初期値) "blu" - 青 "cyn" - シアン "grn" - 緑 "mag" - マゼンタ "red" - 赤 "yel" - 黄 "whi" - 白 "dbl" - ダークブルー "dgn" - ダークグリーン "dmg" - ダークマゼンタ "drd" - ダークレッド "dyl" - ダークイエロー "dgy" - ダークグレー "lgy" - ライトグレー |
| $iSpace | [オプション] 枠線とテキストの間のスペース（スペースの単位） ( 初期値: 0) |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $sLocationの値が不正です。 | |
| 103 - $ivLineStyleの値が不正です。 | |
| 104 - $sColorの値が不正です。 | |
| 106 - $iSpaceが正の数でもゼロでもありません。 | |
| 106 - $iWidthが正の数でもゼロでもありません。 |
注意
"スペースの単位"を設定するには_GUICtrlRichEdit_SetSpaceUnitを呼んで下さい。初期値はインチです。
関連
_GUICtrlRichEdit_GetParaBorder, _GUICtrlRichEdit_SetSpaceUnit
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $iStep = 0, $btnNext
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_AppendText($hRichEdit, "First paragraph")
Report("0. First paragraph: default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "o", 3, "mag", 0.25)
Report("1. Second paragraph: with border (should show in Word)")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, -1)
Report("2. Settings of first paragraph in selection")
Case 3
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "l", 6, "blu")
Report("3. Settings of both paragraphs changed")
Case 4
_GUICtrlRichEdit_SetParaBorder($hRichEdit, Default, ".75gd")
Report("4. Line style changed")
Case 5
; Wordで枠線設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaBorder($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report