現在選択されている段落のインデントを設定します。選択されていない場合、挿入位置に挿入される段落のインデントを設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaIndents($hWnd [, $vLeft = Default [, $iRight = Default [, $iFirstLine = Default]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $vLeft | [オプション] 段落本文の左側のインデント (スペースの単位) 絶対値設定 - 数値 前に対する相対値 - 文字列 - "+<数値>" または "-<数値>" |
| $iRight | [オプション] 段落の右側のインデント (スペースの単位) |
| $iFirstLine | [オプション] 他の行に対して1行目をインデント (スペースの単位) |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $vLeftが数値でも数字からなる文字列でもありません。 | |
| 1022 - $vLeftによってクライアント領域の左側から段落本文が開始しています。 | |
| 103 - $iRightが数値ではありません。 | |
| 105 - $iFirstLineが数値ではありません。 | |
| 200 - 1行目がクライアント領域上側から開始しています。 | |
| 700 - 操作に失敗 |
注意
$iLeft、$iRight、$iFirstLineの正の値は段落中心に向かってのインデントを意味します。
関連
_GUICtrlRichEdit_GetParaIndents, _GUICtrlRichEdit_SetSpaceUnit
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("Para with default indent settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
Report("Added second paragraph")
Case 2
_GUICtrlRichEdit_SetParaIndents($hRichEdit, 0.25, .1)
Report("Changed indent settings of second paragraph")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaIndents($hRichEdit, Default, 0, .2)
Report("Change settings of both paragraphs")
Case 4
; Wordでインデント設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaIndents($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report