現在選択されている段落の影を設定します。選択されていない場合、挿入位置に挿入される段落の影を設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaShading($hWnd [, $iWeight = Default [, $sStyle = Default [, $sForeColor = Default [, $sBackColor = Default]]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $iWeight | [オプション] 前景色のパーセント。残りは背景色。 |
| $sStyle | [オプション] 影のスタイル - 以下のいずれかを格納した文字列: non - 無し dhz - 水平方向に影付け dvt - 垂直方向に影付け ddd - 斜め下向きに影付け dud - 斜め上向きに影付け dgr - 網状に影付け dtr - 格子状に影付け lhz - 水平方向に明るくする lvt - 垂直方向に明るくする ldd - 斜め下向きに明るくする lud - 斜め上向きに明るくする lgr - 網状に明るくするbr> ltr - 格子状に明るくする |
| $sForeColor | [オプション] 以下のいずれか: "blk" - 黒 (初期値) "blu" - 青 "cyn" - シアン "grn" - 緑 "mag" - マゼンタ "red" - 赤 "yel" - 黄 "whi" - 白 "dbl" - ダークブルー "dgn" - ダークグリーン "dmg" - ダークマゼンタ "drd" - ダークレッド "dyl" - ダークイエロー "dgy" - ダークグレー "lgy" - ライトグレー |
| $sBackColor | [オプション] $sForeColorの場合と同様の値 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $iWeightが正の数ではありません。 | |
| 1022 - $iWeightの値が不正です。 | |
| 103 - $sStyleの値が不正です。 | |
| 104 - $sForeColorの値が不正です。 | |
| 105 - $sBackColorの値が不正です。 | |
| 700 - 操作が失敗 |
注意
テキストが選択されている場合、設定対象のデフォルトは選択されているテキストの最初の段落の値です。
関連
_GUICtrlRichEdit_GetParaShading
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaShading($hRichEdit, 60, "ddd", "blu", "dmg")
Report("1. Shading of second paragraph is ")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Style of first paragraph in the selection is ")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaShading($hRichEdit, Default, "dgr")
Report("3. Change shading of both paragraphs")
Case 4
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GUICtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaShading($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report