選択範囲の最小文字位置、最大文字位置を設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetSel($hWnd, $iAnchor, $iActive[, $fHideSel = False])
パラメータ
| $hWnd | コントロールのハンドル |
| $iAnchor | 選択範囲の最初の文字の文字位置 特殊な値: -1 - テキスト末端 |
| $iActive | 選択範囲の最後の文字の文字位置 特殊な値: -1 - テキスト末端 |
| $fHideSel | [オプション] Trueの場合、選択部を非表示にします。 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $iAnchorが正の数でもゼロでも-1でもありません。 | |
| 103 - $iActiveが正の数でもゼロでも-1でもありません。 | |
| 104 - $fHideSelはTrueまたはFalseである必要があります。 |
注意
コントロール内のテキストの最初の文字は文字位置1です。
関連
_GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_GotoCharPos
こちらも参照
MSDNライブラリでEM_EXSETSELを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0, $iCp1
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 3)
Report("1. Initial Character attributes at start of line 1 are")
Case 2
_GuiCtrlRichEdit_AutoDetectURL($hRichEdit, True)
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
$iCp1 = _GuiCtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
_GuiCtrlRichEdit_SetSel($hRichEdit, $iCp1, $iCp1 + 3)
Report("2. Character attributes at start of line 2 are")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $sRet = _GuiCtrlRichEdit_GetCharAttributes($hRichEdit)
$sMsg = $sMsg & @CR & @CR & "Char Attributes=" & $sRet
GUICtrlSetData($lblMsg, $sMsg)
EndFunc ;==>Report