ファイルの内容をコントロールのテキストに設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromFile($hWnd, $sFilespec)
パラメータ
| $hWnd | コントロールのハンドル |
| $sFileSpec | ファイルの指定 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $sFilespecを開けません。 | |
| 1022 - ファイルが空です。 | |
| 700 - 入力しようとした文字数が多すぎます。 |
注意
テキストが選択されている場合、選択部またはコントロール内の全テキストが置換されます。
関連
_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile
こちらも参照
MSDNライブラリでEM_STREAMINを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($lblMsg, "Streamed to gcre.rtf")
Case 2
_GuiCtrlRichEdit_SetText($hRichEdit, "")
_GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($lblMsg, "Streamed from gcre.rtf")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 2, 6)
_GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($lblMsg, "Replaced selection: an intentional mess!")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main