Function Reference

_GUICtrlRichEdit_StreamToVar

コントロールの内容を変数に書き出します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamToVar($hWnd [, $fRtf = True [, $fIncludeCOM=True [, $iOpts=0[, $iCodePage = 0]]]])

 

パラメータ

$hWnd コントロールのハンドル
$fRtf [オプション]
True - リッチテキスト形式 (RTF) (デフォルト)
False - テキストのみ書き出し
$fIncludeCOM [オプション]
True (デフォルト):
    RTF書き出しの場合、全てのCOMオブジェクトを含めます (スペースを消費します)。
    テキストのみの書き出しの場合、COMオブジェクトのテキスト表現を書き出します。
False: COMオブジェクトの代わりにスペースを書き出します。
$iOpts [オプション] 追加オプション:
$SFF_PLAINTRTF - 全ての言語で共通なリッチテキスト句のみ書き出します。
$SF_UNICODE - Unicodeで書き出します。
$iCodePage [オプション] UTF-8とこのコードページを使用するテキストを生成します。
デフォルト: 生成しません。

 

返し値

成功: RTFまたはテキスト
失敗: "" を返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。
1041 - $SFF_PLAINRTFがテキストファイル用として不正です。
1042 - $opts: 不正なオプションです。
1043 - $SF_UNICODEはテキストファイルに対してのみ有効です。
700 - 内部エラー

 

注意

テキストが選択されている場合は選択部のみ書きだされ、それ以外の場合はコントロール内の全てのテキストが書き出されます。

$sFileSpec内の拡張子が.rtfの場合はRTFが書きだされ、それ以外の場合はテキストが書き出されます。

テキストが変更されたかどうかを判定するには_GUICtrlRichEdit_IsModified()を呼んで下さい。

 

関連

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile

 

こちらも参照

MSDNライブラリでEM_STREAMINを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit, $s
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                        GUICtrlSetData($lblMsg, "Streamed to variable")
                    Case 2
                        _GuiCtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Streamed from variable")
                    Case 3
                        _GuiCtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Replaced selection: an intentional mess!")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main