水平境界、垂直境界の現在の幅を取得します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | 次のフォーマットの配列: |
| $aBorders[0] - 水平境界の幅 | |
| $aBorders[1] - 垂直境界の幅 | |
| $aBorders[2] - 長方形の間の境界の幅 | |
| 失敗: | @errorを設定します。 |
注意
なし。
関連
_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVert
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $aInfo, $hStatus
Local $aParts[3] = [75, 150, -1]
; GUIを作成
$hGUI = GUICreate("StatusBar Get Borders", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 境界のサイズを取得
$aInfo = _GUICtrlStatusBar_GetBorders ($hStatus)
MemoWrite("Horizontal border width .: " & $aInfo[0])
MemoWrite("Vertical border width ...: " & $aInfo[1])
MemoWrite("Width between rectangles : " & $aInfo[2])
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite