パーツ数とパーツの境界を設定します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetParts($hWnd[, $iaParts = -1[, $iaPartWidth = 25]])
パラメータ
| $hWnd | コントロールのハンドル |
| $iaParts | [オプション]パーツ数。次のフォーマットのゼロ始まりの整数配列です: $iaParts[0] - パーツ#1の右境界 $iaParts[1] - パーツ#2の右境界 $iaParts[n] - パーツ#nの右境界 |
| $iaPartWidth | [オプション]パーツのサイズ。次のフォーマットのゼロ始まりの整数配列です。 $iaPartWidth[0] - パーツ#1の幅 $iaPartWidth[1] - パーツ#2の幅 $iaPartWidth[n] - パーツ#nの幅 |
返し値
| 成功: | True |
| 失敗: | False |
注意
要素が-1の場合、対応するパーツの右境界はウィンドウの境界まで広がります。
関連
_GUICtrlStatusBar_GetParts
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hStatus
Local $aParts[3] = [75, 150, -1]
; GUIを作成
$hGUI = GUICreate("StatusBar Set Parts", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; パーツを設定/取得
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
$aParts = _GUICtrlStatusBar_GetParts ($hStatus)
For $iI = 1 To $aParts[0]
MemoWrite("Part " & $iI & " width .: " & $aParts[$iI])
Next
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite