ステータスウィンドウがシンプルなテキストを表示するのか、全てのウィンドウパーツを表示するのかを指定します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetSimple($hWnd, $fSimple = True)
パラメータ
| $hWnd | コントロールのハンドル |
| $fSimple | ウィンドウ表示を設定します: True - ウィンドウはシンプルなテキストを表示します False - ウィンドウは複数のパーツを表示します |
返し値
なし。
注意
なし。
関連
_GUICtrlStatusBar_IsSimple
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hStatus
Local $aParts[3] = [75, 150, -1]
; GUIを作成
$hGUI = GUICreate("StatusBar Set Simple", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; シンプル形式を取得/設定
MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple ($hStatus))
_GUICtrlStatusBar_SetSimple ($hStatus, True)
MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple ($hStatus))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite