パーツのツールチップテキストを設定します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetTipText($hWnd, $iPart, $sText)
パラメータ
| $hWnd | コントロールのハンドル |
| $iPart | ゼロ始まりのパーツインデックス |
| $sText | ツールチップテキストを指定します |
返し値
なし。
注意
ツールチップを埋め込むためには$SBARS_TOOLTIPSスタイルを使用してステータスバーを作成する必要があります。
関連
_GUICtrlStatusBar_GetTipText
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
Example1()
Example2()
Func Example1()
Local $hGUI, $hIcon, $hStatus
Local $aParts[4] = [75, 150, 300, 400]
; GUIを作成
$hGUI = GUICreate("(Example 1) StatusBar Set Tip Text", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI, -1, "", $SBARS_TOOLTIPS)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; パーツを設定
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
_GUICtrlStatusBar_SetText ($hStatus, "Force tip to be shown when text is more than fits in the box", 1)
; アイコンを設定
$hIcon = _WinAPI_LoadShell32Icon (23)
_GUICtrlStatusBar_SetIcon ($hStatus, 0, $hIcon)
; テキストチップを設定
_GUICtrlStatusBar_SetTipText ($hStatus, 0, "Tip works when only icon in part or text exceeds part")
_GUICtrlStatusBar_SetTipText ($hStatus, 1, "Force tip to be shown when text is more than fits in the box")
MemoWrite("Hold Mouse Cursor over part to see tip." & @CRLF)
; テキストチップを表示
MemoWrite("Text tip 1 .: " & _GUICtrlStatusBar_GetTipText ($hStatus, 0) & @CRLF)
MemoWrite("Text tip 2 .: " & _GUICtrlStatusBar_GetTipText ($hStatus, 1))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; アイコンを解放
_WinAPI_DestroyIcon ($hIcon)
GUIDelete()
EndFunc ;==>Example1
Func Example2()
Local $hGUI, $hStatus
Local $aParts[4] = [75, 150, 300, 400]
; GUIを作成
$hGUI = GUICreate("(Example 2) StatusBar Set Tip Text", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI, -1, "", $SBARS_TOOLTIPS)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; パーツを設定
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
_GUICtrlStatusBar_SetText ($hStatus, "Force tip to be shown when text is more than fits in the box", 1)
; アイコンを設定
_GUICtrlStatusBar_SetIcon ($hStatus, 0, 23, "shell32.dll")
; テキストチップを設定
_GUICtrlStatusBar_SetTipText ($hStatus, 0, "Tip works when only icon in part or text exceeds part")
_GUICtrlStatusBar_SetTipText ($hStatus, 1, "Force tip to be shown when text is more than fits in the box")
MemoWrite("Hold Mouse Cursor over part to see tip." & @CRLF)
; テキストチップを表示
MemoWrite("Text tip 1 .: " & _GUICtrlStatusBar_GetTipText ($hStatus, 0) & @CRLF)
MemoWrite("Text tip 2 .: " & _GUICtrlStatusBar_GetTipText ($hStatus, 1))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example2
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite