Function Reference

_GUICtrlToolbar_GetButtonRect

ボタンの外接長方形を取得します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonRect($hWnd, $iCommandID)

 

パラメータ

$hWnd コントロールのハンドル
$iCommandID ボタンのコマンドID

 

返し値

成功: 次のフォーマットの配列:
        [0] - 長方形の左上隅のX座標
        [1] - 長方形の左上隅のY座標
        [2] - 長方形の右下隅のX座標
        [3] - 長方形の右下隅のY座標

 

注意

なし。

 

関連

_GUICtrlToolbar_GetButtonRectEx

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aRect
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; セーブボタンの長方形を表示
    $aRect = _GUICtrlToolbar_GetButtonRect ($hToolbar, $idSave)
    MemoWrite("Save Button Rect")
    MemoWrite("----------------")
    MemoWrite("Left ...: " & $aRect[0])
    MemoWrite("Top ....: " & $aRect[1])
    MemoWrite("Right ..: " & $aRect[2])
    MemoWrite("Bottom .: " & $aRect[3])

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite