Function Reference

_GUICtrlToolbar_GetInsertMark

現在の挿入マークを取得します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetInsertMark($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 次のフォーマットの配列:
        [0] - 挿入マーク位置のゼロ始まりのインデックス。-1の場合はマークなし。
        [1] - iButtonに対する挿入マークの定義位置:
        0 - 左側
        1 - 右側
        2 - ツールバーの背景

 

注意

なし。

 

関連

_GUICtrlToolbar_SetInsertMark

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aMark
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 挿入マークの設定
    _GUICtrlToolbar_SetInsertMarkColor($hToolbar, 0xFF0000)
    _GUICtrlToolbar_SetInsertMark($hToolbar, 1, 1)

    ; 挿入マークの表示
    $aMark = _GUICtrlToolbar_GetInsertMark($hToolbar)
    MemoWrite("Index ........: " & $aMark[0])
    MemoWrite("Relationship .: " & $aMark[1])
    MemoWrite("Mark color ...: 0x" & Hex(_GUICtrlToolbar_GetInsertMarkColor($hToolbar), 6))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite