Function Reference

_GUICtrlToolbar_GetStyleCustomErase

コントロールがNM_CUSTOMDRAW通知メッセージを発生するかどうかを表します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetStyleCustomErase($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

True: スタイルが設定されています
False: スタイルが設定されていません

 

注意

なし。

 

関連

_GUICtrlToolbar_SetStyleCustomErase

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $fStyle
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; コントロールのスタイルを変更
    $fStyle = _GUICtrlToolbar_GetStyleCustomErase($hToolbar)
    MemoWrite("Toolbar sends custom erase .: " & $fStyle)
    _GUICtrlToolbar_SetStyleCustomErase($hToolbar, Not $fStyle)
    MemoWrite("Toolbar sends custom erase .: " & _GUICtrlToolbar_GetStyleCustomErase($hToolbar))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite