ボタンの拡張情報を設定します。
#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonInfo($hWnd, $iCommandID[, $iImage = -3[, $iState = -1[, $iStyle = -1[, $iWidth = -1[, $iParam = -1]]]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $iCommandID | ボタンのコマンドID |
| $iImage | [オプション]ボタン画像のゼロ始まりのインデックス。 このパラメータを-1に設定するとコントロールは画像インデックスが必要な場合にそれを取得するために$TBN_GETDISPINFO通知を送信します。 -2に設定するとボタンに画像を設定しません。ボタンはテキスト用のスペースのみを考慮して配置されます。 ボタンがセパレータの場合、この値はピクセル単位でのセパレータの幅です。 |
| $iState | [オプション]ボタンの状態。次のものの組み合わせです: $TBSTATE_CHECKED - ボタンはクリックされています $TBSTATE_PRESSED - ボタンがクリックされた状態になります $TBSTATE_ENABLED - ボタンがユーザー入力を受け入れる様にします $TBSTATE_HIDDEN - ボタンは非表示になります $TBSTATE_INDETERMINATE - ボタンがグレイアウトします $TBSTATE_WRAP - ボタンの後ろで改行します $TBSTATE_ELLIPSES - ボタンのテキストは切り捨てられます $TBSTATE_MARKED - ボタンに印が付きます |
| $iStyle | [オプション]ボタンのスタイル。次のものの組み合わせです: $BTNS_AUTOSIZE - コントロールは標準的な幅を割り当てません $BTNS_BUTTON - 標準的なボタン $BTNS_CHECK - 押した状態/押してない状態を切り替えます $BTNS_CHECKGROUP - 他のボタンが押されるまで押された状態のままです $BTNS_DROPDOWN - リストを表示できるドロップダウンスタイルのボタンを作成します $BTNS_GROUP - 他のボタンが押されるまで押された状態のままです $BTNS_NOPREFIX - ボタンテキストにアクセラレータの接頭辞を表示しません $BTNS_SEP - セパレータを作成 $BTNS_SHOWTEXT - ボタンテキストが表示されるように指定します $BTNS_WHOLEDROPDOWN - ボタンにドロップダウン用の矢印が表示されるように指定します |
| $iWidth | [オプション]ボタンの幅 |
| $iParam | [オプション]アプリケーション定義の値 |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GUICtrlToolbar_GetButtonInfo, $tagTBBUTTONINFO
例
#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aButton
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; GUIを作成
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create ($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; 標準的なシステムのビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep ($hToolbar)
_GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)
; セーブボタンの情報を設定
_GUICtrlToolbar_SetButtonInfo ($hToolbar, $idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)
; セーブボタンの情報を表示
$aButton = _GUICtrlToolbar_GetButtonInfo ($hToolbar, $idSave)
MemoWrite("Image index ....: " & $aButton[0])
MemoWrite("State flags ....: " & $aButton[1])
MemoWrite("Style flags ....: " & $aButton[2])
MemoWrite("Button width ...: " & $aButton[3])
MemoWrite("Param ..........: " & $aButton[4])
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite