ツールバーに追加されるボタンのサイズを設定します。
#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonSize($hWnd, $iHeight, $iWidth)
パラメータ
| $hWnd | コントロールのハンドル |
| $iHeight | ピクセル単位でのボタンの高さ |
| $iWidth | ピクセル単位でのボタンの幅 |
返し値
成功: True
注意
ツールバーに追加する前のボタンにのみサイズ設定可能です。
関連
_GUICtrlToolbar_GetButtonSize
例
#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aSize
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; GUIを作成
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; 標準的なシステムのビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; ボタンのサイズを表示
$aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
MemoWrite("Button height : " & $aSize[0])
MemoWrite("Button width .: " & $aSize[1])
_GUICtrlToolbar_SetButtonSize($hToolbar, $aSize[0], $aSize[1] + 10)
$aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
MemoWrite("New Button Size")
MemoWrite("Button height : " & $aSize[0])
MemoWrite("Button width .: " & $aSize[1])
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite