ホットボタン用の画像リストを設定します。
#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetHotImageList($hWnd, $hImageList)
パラメータ
| $hWnd | コントロールのハンドル |
| $hImageList | 設定される画像リストのハンドル |
返し値
成功: 以前にホットボタンの表示に使用されていた画像リストのハンドル
注意
なし。
関連
_GUICtrlToolbar_GetHotImageList
例
#include <GuiToolbar.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar, $hNormal, $hDisabled, $hHot
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
Local Enum $idRed = 1000, $idGreen, $idBlue
; GUIを作成
$hGUI = GUICreate("Toolbar", 400, 300)
GUISetBkColor(0xffff00)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; 通常の画像リストを作成
$hNormal = _GUIImageList_Create(32, 24)
_GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
_GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
_GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))
_GUICtrlToolbar_SetImageList($hToolbar, $hNormal)
; 無効用の画像リストを作成
$hDisabled = _GUIImageList_Create(32, 24)
_GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xCCCCCC, 32, 24))
_GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xCCCCCC, 32, 24))
_GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xCCCCCC, 32, 24))
_GUICtrlToolbar_SetDisabledImageList($hToolbar, $hDisabled)
; ホット用の画像リストを作成
$hHot = _GUIImageList_Create(32, 24)
_GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0x111111, 32, 24))
_GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0x888888, 32, 24))
_GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0xAAAAAA, 32, 24))
_GUICtrlToolbar_SetHotImageList($hToolbar, $hHot)
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idRed, 0)
_GUICtrlToolbar_AddButton($hToolbar, $idGreen, 1)
_GUICtrlToolbar_AddButton($hToolbar, $idBlue, 2)
; 青いボタンを無効化
_GUICtrlToolbar_EnableButton($hToolbar, $idBlue, False)
; 画像リストのハンドルを表示
MemoWrite("Disabled list handle .: 0x" & Hex(_GUICtrlToolbar_GetDisabledImageList($hToolbar)))
MemoWrite("Hot list handle ......: 0x" & Hex(_GUICtrlToolbar_GetHotImageList($hToolbar)))
MemoWrite("Normal list handle ...: 0x" & Hex(_GUICtrlToolbar_GetImageList($hToolbar)))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite