コントロールのスタイルを設定します。
#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetStyle($hWnd, $iStyle)
パラメータ
| $hWnd | コントロールのハンドル |
| $iStyle | コントロールのスタイル。次のものの組み合わせです: $TBSTYLE_TOOLTIPS - ツールチップコントロールを作成します $TBSTYLE_WRAPABLE - 複数行のボタンを持つツールバーを作成します $TBSTYLE_ALTDRAG - ユーザーがドラッグによってツールバーのボタン位置を変更できるようにします $TBSTYLE_FLAT - 平らなツールバーを作成します $TBSTYLE_LIST - ビットマップの隣にボタンテキストを持つ平らなツールバーを作成します $TBSTYLE_CUSTOMERASE - $WM_ERASEBKGNDメッセージ処理時に$NM_CUSTOMDRAWメッセージを送信します $TBSTYLE_REGISTERDROP - ドロップターゲットオブジェクトを要求するために$TBN_GETOBJECTメッセージを送信します $TBSTYLE_TRANSPARENT - 透明なツールバーを作成します |
返し値
なし。
注意
なし。
関連
_GUICtrlToolbar_GetStyle
例
#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; GUIを作成
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; コントロールスタイルを設定
_GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))
; 標準的なシステムのビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; コントロールスタイルを表示
MemoWrite("Toolbar style .: 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite