ツールバーにツールチップコントロールを関連付けます。
#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetToolTips($hWnd, $hToolTip)
パラメータ
| $hWnd | コントロールのハンドル |
| $hToolTip | ツールチップコントロールのハンドル |
返し値
なし。
注意
この関数を呼ぶ前にコントロールに追加されたボタンはツールチップコントロールに登録されません。
関連
_GUICtrlToolbar_GetToolTips
例
#include <GuiToolbar.au3>
#include <GuiToolTip.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global Enum $idNew = 1000, $idOpen, $idSave, $idHelp
_Main()
Func _Main()
Local $hGUI, $hToolbar, $hToolTip
; GUIを作成
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
GUISetState()
; ツールチップを作成
$hToolTip = _GUIToolTip_Create($hToolbar)
_GUICtrlToolbar_SetToolTips($hToolbar, $hToolTip)
; 標準的なシステムのビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; ツールチップのハンドルを表示
MsgBox(4096, "Information", "ToolTip handle .: 0x" & Hex(_GUICtrlToolbar_GetToolTips($hToolbar)))
; ユーザーが終了するまでループ
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; WM_NOTIFYメッセージを制御
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
Local $tInfo, $iID, $iCode
$tInfo = DllStructCreate($tagNMTTDISPINFO, $ilParam)
$iCode = DllStructGetData($tInfo, "Code")
If $iCode = $TTN_GETDISPINFO Then
$iID = DllStructGetData($tInfo, "IDFrom")
Switch $iID
Case $idNew
DllStructSetData($tInfo, "aText", "New")
Case $idOpen
DllStructSetData($tInfo, "aText", "Open")
Case $idSave
DllStructSetData($tInfo, "aText", "Save")
Case $idHelp
DllStructSetData($tInfo, "aText", "Help")
EndSwitch
EndIf
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_NOTIFY