イメージリスト内の画像の高さを取得します。
#Include <GuiImageList.au3>
_GUIImageList_GetIconHeight($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | 各画像のピクセル単位での高さ |
| 失敗: | 0 |
注意
なし。
関連
_GUIImageList_GetIconSize, _GUIImageList_GetIconWidth, _GUIImageList_GetIconSizeEx
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hImage, $hGUI, $hDC
$hGUI = GUICreate("ImageList Get Icon Height", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create(32, 24)
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))
; 画像を描画
$hDC = _WinAPI_GetDC($hGUI)
_GUIImageList_Draw($hImage, 0, $hDC, 4, 4)
_GUIImageList_Draw($hImage, 1, $hDC, 40, 4)
_GUIImageList_Draw($hImage, 2, $hDC, 76, 4)
_WinAPI_ReleaseDC($hGUI, $hDC)
; イメージリストのアイコンのサイズを表示
MemoWrite("Image width : " & _GUIImageList_GetIconWidth($hImage))
MemoWrite("Image height: " & _GUIImageList_GetIconHeight($hImage))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite