スクロールバーの有効/無効を切り替えます。
#Include <GuiScrollBars.au3>
_GUIScrollBars_EnableScrollBar($hWnd[, $wSBflags = $SB_BOTH[, $wArrows = $ESB_ENABLE_BOTH]])
パラメータ
| $hWnd | ウィンドウのハンドル |
| $wSBflags | [オプション]スクロールバーの種類を指定します。このパラメータは次の値のいずれかです: $SB_BOTH - 指定されたウィンドウに関連付けられた水平、垂直スクロールバーの矢印の有効/無効を切り替えます。 $SB_CTL - スクロールバーがスクロールバーコントロールであることを表します。$hWndパラメータはスクロールバーコントロールのハンドルでなければなりません。 $SB_HORZ - 指定されたウィンドウに関連付けられた水平スクロールバーの矢印の有効/無効を切り替えます。 $SB_VERT - 指定されたウィンドウに関連付けられた垂直スクロールバーの矢印の有効/無効を切り替えます。 |
| $wArrows | [オプション]スクロールバーのどの矢印を有効/無効にするかを指定します。 このパラメータは次の値のうちの1つです: $ESB_DISABLE_BOTH - スクロールバーの両方の矢印を無効 $ESB_DISABLE_DOWN - 垂直スクロールバーの下矢印を無効 $ESB_DISABLE_LEFT - 水平スクロールバーの左矢印を無効 $ESB_DISABLE_LTUP - 水平スクロールバーの左矢印または垂直スクロールバーの上矢印 $ESB_DISABLE_RIGHT - 水平スクロールバーの右矢印を無効 $ESB_DISABLE_RTDN - 水平スクロールバーの右矢印または垂直スクロールバーの下矢印 $ESB_DISABLE_UP - 垂直スクロールバーの上矢印を無効 $ESB_ENABLE_BOTH - スクロールバーの両方の矢印を有効 |
返し値
| 成功: | True |
| 失敗: | False |
注意
上記の定数にはScrollBarConstants.au3が必要です。
関連
_GUIScrollBars_ShowScrollBar
こちらも参照
MSDNライブラリでEnableScrollBarを検索して下さい。
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
Opt("MustDeclareVars", 1)
Global $iMemo
_Main()
Func _Main()
Local $GUIMsg, $hGUI
$hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetBkColor(0x88AABB)
GUISetState()
_GUIScrollBars_Init($hGUI)
MemoWrite("Disable down arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_DOWN))
Sleep(3000)
MemoWrite("Disable up arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_UP))
Sleep(3000)
MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_ENABLE_BOTH))
Sleep(3000)
MemoWrite("Disable left arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_LEFT))
Sleep(3000)
MemoWrite("Disable right arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_RIGHT))
Sleep(3000)
MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_ENABLE_BOTH))
While 1
$GUIMsg = GUIGetMsg()
Switch $GUIMsg
Case $GUI_EVENT_CLOSE;, $nExititem
ExitLoop
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite