スクロールバーコンポーネントの状態を取得します。
#Include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollBarRGState($hWnd, $idObject)
パラメータ
| $hWnd | ウィンドウのハンドル |
| $idObject | スクロールバーオブジェクトを指定します。このパラメータは次の値のいずれかです: $OBJID_CLIENT - $hWndパラメータはスクロールバーコントロールのハンドルです。 $OBJID_HSCROLL - $hWndウィンドウの水平スクロールバー。 $OBJID_VSCROLL - $hWndウィンドウの垂直スクロールバー。 |
返し値
| 成功: | 次のフォーマットの配列: |
| [0] - スクロールバー自体 | |
| [1] - 上または右矢印ボタン | |
| [2] - 上ページ送りまたは右ページ送り領域 | |
| [3] - スクロールボックス(つまみ) | |
| [4] - 下ページ送りまたは左ページ送り領域 | |
| [5] - 下または左矢印ボタン | |
| 失敗: | @errorを設定します。 |
注意
上記の定数にはScrollBarConstants.au3が必要です。
関連
_GUIScrollBars_GetScrollBarInfoEx
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
Opt("MustDeclareVars", 1)
Global $iMemo
_Main()
Func _Main()
Local $GUIMsg, $hGUI, $aRGState
$hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
$iMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetBkColor(0x88AABB)
GUISetState()
_GUIScrollBars_Init($hGUI)
$aRGState = _GUIScrollBars_GetScrollBarRGState($hGUI, $OBJID_HSCROLL)
MemoWrite("Horizontal (Before)" & @CRLF & "--------------------------------------")
For $x = 0 To 5
MemoWrite("rgstate[" & $x & "]...: " & $aRGState[$x])
Next
MemoWrite(@CRLF & "Disable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_BOTH) & @CRLF)
$aRGState = _GUIScrollBars_GetScrollBarRGState($hGUI, $OBJID_HSCROLL)
MemoWrite("Horizontal (After)" & @CRLF & "--------------------------------------")
For $x = 0 To 5
MemoWrite("rgstate[" & $x & "]...: " & $aRGState[$x])
Next
While 1
$GUIMsg = GUIGetMsg()
Switch $GUIMsg
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite