ブラウザ上で単純な一連の動作を実行します。
#include <IE.au3>
_IEAction ( ByRef $o_object, $s_action )
パラメータ
| $o_object | InternetExplorer.Applicationのオブジェクト変数 |
| $s_action | 選択動作 (注意を参照) |
返し値
| 成功: | 1を返します |
| 失敗: | 0を返し@ERRORを設定します |
| @Error: | 0 ($_IEStatus_Success) = 正常終了 |
| 3 ($_IEStatus_InvalidDataType) = 無効なデータ型 | |
| 4 ($_IEStatus_InvalidObjectType) = 無効なオブジェクト型 | |
| 5 ($_IEStatus_InvalidValue) = 無効な値 | |
| @Extended: | 無効なパラメータの番号を格納します |
注意
| 動作 | 説明 |
| "back" | 履歴リストの1つ後ろのアイテムに移動します。 |
| "blur" | 要素からフォーカスをはずします。タブ順の次の要素にはフォーカスをあわせません。 |
| "click" | 指定した要素のクリックをシミュレーションします。 |
| "copy" | 現在の選択範囲をクリップボードにコピーします。 |
| "cut" | 現在の選択範囲をクリップボードにコピーした後、削除します。 |
| "delete" | 現在の選択範囲を削除します。 |
| "disable" | 指定した要素を無効にします。 |
| "enable" | 指定した要素を有効にします。 |
| "focus" | 要素にフォーカスをあわせます。 |
| "forward" | 履歴リストの1つ前のアイテムに移動します。 |
| "home" | 現在のホーム、またはスタートページに移動します。 |
| "invisible" | オブジェクトの状態を非表示にします。 |
| "paste" | 現在の選択範囲にクリップボードの内容を上書きします。 |
| "print" | ユーザーが現在のページを印刷できるように印刷ダイアログボックスを開きます。 |
| "printdefault" | デフォルトのプリンターで直接印刷をおこないます(ダイアログ無し)。 |
| "quit" | オブジェクトを閉じます。 |
| "refresh" | 現在のドキュメントを再読み込みします。 |
| "saveas" | 現在のWebページをファイルに保存するためのダイアログボックスを開きます。 |
| "search" | 現在の検索ページに移動します。 |
| "selectall" | ドキュメント全体を選択します。 |
| "stop" | 読み込み中の移動、ダウンロード処理をキャンセルします。またBGMやアニメーションなどの動的ページ要素を停止します。 |
| "unselect" | 現在の選択範囲設定を解除します。 |
| "visible" | オブジェクトの状態を表示にします。 |
関連
_IEPropertySet, _IELoadWait
例
; *******************************************************
; 例 1 - "form"のサンプルをブラウザで開き、サブミットボタンの参照を名前で取得し"click"する。
;このフォーム書き込みのテクニックは便利。なぜなら多くのフォームはJavaScriptコードで書かれており
;そのサブミットボタンの"onClick"イベントは_IEFormSubmit()の動作を邪魔するから。
; *******************************************************
;
#include <IE.au3>
$oIE = _IE_Example ("form")
$oSubmit = _IEGetObjByName ($oIE, "submitExample")
_IEAction ($oSubmit, "click")
_IELoadWait ($oIE)
; *******************************************************
; 例 2 - clickを使う代わりに、要素にフォーカスを合わせてControlSendでEnterを送信している以外は例 １と同じ。
;このテクニックはクリック動作に関係するブラウザ側のスクリプトコードが
;あなたのコードによるコントロール自動制御を邪魔する場合に使用してみてください
; *******************************************************
;
#include <IE.au3>
$oIE = _IE_Example ("form")
$oSubmit = _IEGetObjByName ($oIE, "submitExample")
$hwnd = _IEPropertyGet($oIE, "hwnd")
_IEAction ($oSubmit, "focus")
ControlSend($hwnd, "", "[CLASS:Internet Explorer_Server; INSTANCE:1]", "{Enter}")
; 警告ウィンドウを待ち、OKをクリック
WinWait("Windows Internet Explorer", "ExampleFormSubmitted")
ControlClick("Windows Internet Explorer", "ExampleFormSubmitted", "[CLASS:Button; TEXT:OK; Instance:1;]")
_IELoadWait ($oIE)