ドキュメント内のフォームを格納したコレクションオブジェクト変数、またはインデックスと対応するフォームを返します。
#include <IE.au3>
_IEFormGetCollection ( ByRef $o_object [, $i_index = -1] )
パラメータ
| $o_object | InternetExplorer.Applicationのオブジェクト変数、ウィンドウ、フレーム、またはアイフレームオブジェクト |
| $i_index | [オプション]コレクションを返すか、インデックスの要素を返すかを指定します 0 または正の整数の場合、そのインデックスのインスタンスを返します -1 = (デフォルト) コレクションを返します |
返し値
| 成功: | ドキュメント内の全てのフォームのコレクションのオブジェクト変数を返します。@EXTENDED = フォームの数 |
| 失敗: | 0を返し@ERRORを設定します |
| @Error: | 0 ($_IEStatus_Success) = 正常終了 |
| 3 ($_IEStatus_InvalidDataType) = 無効なデータ型 | |
| 5 ($_IEStatus_InvalidValue) = 無効な値 | |
| 7 ($_IEStatus_NoMatch) = 一致するものがありません | |
| @Extended: | 無効なパラメータの番号が格納されています |
注意
なし。
関連
_IEFormGetObjByName, _IEFormReset, _IEFormSubmit
例
; *******************************************************
; 例 1 - 0始まりのインデックスを使って指定したフォームへの参照を取得
; 今回はページの1番目のフォーム
; *******************************************************
;
#include <IE.au3>
$oIE = _IECreate ("http://www.google.com")
$oForm = _IEFormGetCollection ($oIE, 0)
$oQuery = _IEFormElementGetCollection ($oForm, 1)
_IEFormElementSetValue ($oQuery, "AutoIt IE.au3")
_IEFormSubmit ($oForm)
; *******************************************************
; 例 2 - ページ上のフォームのコレクションへの参照を取得
; それぞれの情報を表示しながらループ
; *******************************************************
;
#include <IE.au3>
$oIE = _IECreate ("http://www.autoitscript.com")
$oForms = _IEFormGetCollection ($oIE)
MsgBox(0, "Forms Info", "There are " & @extended & " forms on this page")
For $oForm In $oForms
MsgBox(0, "Form Info", $oForm.name)
Next
; *******************************************************
; 例 3 - ページ上のフォームのコレクションへの参照を取得
; それぞれの情報を表示しながらループ
; インデックスの使用法をデモ
; *******************************************************
;
#include <IE.au3>
$oIE = _IECreate ("http://www.autoitscript.com")
$oForms = _IEFormGetCollection ($oIE)
$iNumForms = @extended
MsgBox(0, "Forms Info", "There are " & $iNumForms & " forms on this page")
For $i = 0 to $iNumForms - 1
$oForm = _IEFormGetCollection ($oIE, $i)
MsgBox(0, "Form Info", $oForm.name)
Next