共有リソースとの間に確立されたすべての接続をリストアップします。
#Include <NetShare.au3>
_Net_Share_ConnectionEnum($sServer, $sQualifier)
パラメータ
| $sServer |
この関数が実行されるリモートサーバーのDNSまたはNetBIOS名を指定する文字列。 このパラメータが空白の場合、ローカルコンピュータが使用されます。 |
| $sQualifier |
目的のコンピュータ名または共有名を指定します。 共有名の場合、この共有名に対して確立されているすべての接続がリストアップされます。 コンピュータ名の場合、この関数はそのコンピュータから指定されたサーバーに対して 確立されているすべての接続をリストアップします。 |
返し値
| 成功: | 次のフォーマットの配列: |
| [0][0] - 配列内のエントリー数 | |
| [1][0] - 接続の識別番号 | |
| [1][1] - 接続の種類。以下のものの組み合わせ: | |
| $STYPE_DISKTREE - プリントキュー | |
| $STYPE_PRINTQ - ディスクドライブ | |
| $STYPE_DEVICE - 通信機器 | |
| $STYPE_IPC - IPC | |
| $STYPE_SPECIAL - IPC$用またはサーバーのリモート管理用の特別な共有 | |
| $STYPE_TEMPORARY - 一時的な共有 | |
| [1][2] - 現在、接続の結果として開いているファイルの数 | |
| [1][3] - 接続上のユーザー数 | |
| [1][4] - 接続が確立されてからの秒数 | |
| [1][5] - リソースを共有しているサーバーがユーザーレベルセキュリティで実行されている場合、どのユーザーが接続を確立したかを表します。サーバーが共有レベルセキュリティで実行されている場合、どのコンピュータが接続を確立したかを表します。 | |
| [1][6] - サーバーの共有リソースの共有名またはクライアントのコンピュータ名のいずれかを指定します。 | |
| 失敗: | @errorを設定します。 |
注意
この関数の実行には管理者権限、サーバーまたはプリントオペレータまたはパワーユーザーグループのメンバー権限が必要です
関連
_Net_Share_FileEnum, _Net_Share_SessionEnum, _Net_Share_ShareEnum
こちらも参照
MSDNライブラリでNetConnectionEnumを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $sServer, $sShare, $aInfo
; GUI作成
$hGUI = GUICreate("NetShare", 400, 300)
; メモコントロール作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; サーバー情報、共有情報の取得
$sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
If @error Then Exit
$sShare = InputBox("NetWork Demo", "Enter Share Name:", "MyShare", "", 200, 130)
If @error Then Exit
; ネットワーク接続の列挙
$aInfo = _Net_Share_ConnectionEnum ($sServer, $sShare)
MemoWrite("Error ...................: " & @error)
MemoWrite("Entries read ............: " & $aInfo[0][0])
For $iI = 1 To $aInfo[0][0]
MemoWrite("Connection ID ...........: " & $aInfo[$iI][0])
MemoWrite("Connection type..........: " & _Net_Share_ResourceStr ($aInfo[$iI][1]))
MemoWrite("Number of files open ....: " & $aInfo[$iI][2])
MemoWrite("Number of users .........: " & $aInfo[$iI][3])
MemoWrite("Connection time .........: " & $aInfo[$iI][4])
MemoWrite("Username ................: " & $aInfo[$iI][5])
MemoWrite("Network name ............: " & $aInfo[$iI][6])
MemoWrite()
Next
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモにメッセージ書き込み
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite