サーバーリソースを共有します。
#Include <NetShare.au3>
_Net_Share_ShareAdd($sServer, $sShare, $iType, $sPath [, $sComment = "" [, $iMaxUses = -1]])
パラメータ
| $sServer | この関数が実行されるリモートサーバーのDNSまたはNetBIOS名を指定する文字列。 If このパラメータが空白の場合、ローカルコンピュータが使用されます |
| $sShare | リソースの共有名 |
| $iType | 共有リソースの種類を指定します。次のものの組み合わせです: $STYPE_DISKTREE - ディスクドライブ $STYPE_PRINTQ - プリントキュー $STYPE_DEVICE - 通信機器 $STYPE_IPC - IPC $STYPE_SPECIAL - IPC$用またはサーバーのリモート管理用の特別な共有 $STYPE_TEMPORARY - 一時的な共有 |
| $sPath |
共有リソースのローカルパス。ディスクの場合、これは共有されるパスです。 プリントキューの場合、これは共有されるプリントキューの名前です。 |
| $sComment | [オプション]共有リソースのコメントを格納した文字列 |
| $iMaxUses | [オプション]
リソースが提供することができる最大接続数。 この値を-1にすると接続数を無制限にできます。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
管理者、システムオペレータ、パワーユーザーローカルグループのメンバーのみこの関数を呼んでファイル共有を追加することができます。
関連
_Net_Share_ShareCheck, _Net_Share_ShareDel
こちらも参照
MSDNライブラリでNetApiBufferFreeを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $iI, $aInfo
Local Const $sShareName = "AutoIt Share"
; GUI作成
$hGUI = GUICreate("NetShare", 400, 300)
; メモコントロール作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 共有が存在するか確認
If _Net_Share_ShareCheck (@ComputerName, $sShareName) = -1 Then
; ローカルコンピュータ上に共有を作成
_Net_Share_ShareAdd (@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
If @error Then MsgBox (4096, "Information", "Share add error : " & @error)
MemoWrite ("Share added")
Else
MemoWrite ("Share exists")
EndIf
; すべてのローカル共有の情報を表示
$aInfo = _Net_Share_ShareEnum (@ComputerName)
MemoWrite("Entries read ............: " & $aInfo[0][0])
For $iI = 1 To $aInfo[0][0]
MemoWrite("Share name ..............: " & $aInfo[$iI][0])
MemoWrite("Share type...............: " & _Net_Share_ResourceStr ($aInfo[$iI][1]))
MemoWrite("Comment .................: " & $aInfo[$iI][2])
MemoWrite("Permissions .............: " & _Net_Share_PermStr ($aInfo[$iI][3]))
MemoWrite("Maximum connections .....: " & $aInfo[$iI][4])
MemoWrite("Current connections .....: " & $aInfo[$iI][5])
MemoWrite("Local path ..............: " & $aInfo[$iI][6])
MemoWrite("Password ................: " & $aInfo[$iI][7])
MemoWrite()
Next
; 共有を削除
_Net_Share_ShareDel (@ComputerName, $sShareName)
If @error Then MsgBox (4096, "Information", "Share delete error : " & @error)
MemoWrite("Share deleted")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモにメッセージ書き込み
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite