サーバー上の特定の共有リソースの情報を設定します。
#Include <NetShare.au3>
_Net_Share_ShareSetInfo($sServer, $sShare, $sComment, $iMaxUses)
パラメータ
| $sServer | この関数が実行されるリモートサーバーのDNSまたはNetBIOS名を指定する文字列。 If このパラメータが空白の場合、ローカルコンピュータが使用されます。 |
| $sShare | 情報を設定する共有の名前を指定します |
| $sComment | 共有リソースのオプションコメントを格納した文字列 |
| $iMaxUses | リソースが提供することができる最大接続数を表します。この値を-1にすると接続数を無制限にできます。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
管理者、サーバーオペレータ、パワーユーザーローカルグループまたはプリント、サーバーオペレータグループメンバー権限を持っている者のみこの関数を実行できます。
関連
_Net_Share_ShareGetInfo
こちらも参照
MSDNライブラリでNetShareSetInfoを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $iI, $aInfo
Local Const $sShareName = "AutoIt Share"
; GUI作成
$hGUI = GUICreate("NetShare", 400, 300)
; メモコントロール作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; 共有が存在するか確認
If _Net_Share_ShareCheck (@ComputerName, $sShareName) = -1 Then
; ローカルコンピュータ上に共有を作成
_Net_Share_ShareAdd (@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
If @error Then MsgBox(4096, "Information", "Share add error : " & @error)
MemoWrite("Share added")
Else
MemoWrite("Share exists")
EndIf
; 共有の情報を変更
_Net_Share_ShareSetInfo (@ComputerName, $sShareName, "New Comment", 4)
; 追加した共有の情報を表示
$aInfo = _Net_Share_ShareGetInfo (@ComputerName, $sShareName)
MemoWrite("Share name ..............: " & $aInfo[0])
MemoWrite("Share type...............: " & _Net_Share_ResourceStr ($aInfo[1]))
MemoWrite("Comment .................: " & $aInfo[2])
MemoWrite("Permissions .............: " & _Net_Share_PermStr ($aInfo[3]))
MemoWrite("Maximum connections .....: " & $aInfo[4])
MemoWrite("Current connections .....: " & $aInfo[5])
MemoWrite("Local path ..............: " & $aInfo[6])
MemoWrite("Password ................: " & $aInfo[7])
; 共有を削除
_Net_Share_ShareDel (@ComputerName, $sShareName)
If @error Then MsgBox(4096, "Information", "Share delete error : " & @error)
MemoWrite("Share deleted")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモにメッセージ書き込み
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite