指定されたミリ秒数を時間、分および秒に変換します。
#Include <Date.au3>
_TicksToTime($iTicks, ByRef $iHours, ByRef $iMins, ByRef $iSecs)
パラメータ
| $iTicks | ミリ秒数。 |
| $iHours | 時間数が代入される変数。 |
| $iMins | 分数が代入される変数。 |
| $iSecs | 秒数が代入される変数。 |
返し値
| 成功: | 1 |
| 失敗: | 0 |
| @Error: | 0 - 正常終了 |
| 1 - $iTicksは整数ではありません |
注意
なし。
関連
_TimeToTicks
例
; *** タイマーウィンドウ表示のデモ
#include <GUIConstantsEx.au3>
#include <Date.au3>
Opt("TrayIconDebug", 1)
Opt("MustDeclareVars", 1)
Global $timer, $Secs, $Mins, $Hour, $Time
_Main()
Func _Main()
; GUI作成
GUICreate("Timer", 120, 50)
GUICtrlCreateLabel("00:00:00", 10, 10)
GUISetState()
; タイマー開始
$timer = TimerInit()
AdlibRegister("Timer", 50)
;
While 1
;FileWriteLine("debug.log",@min & ":" & @sec & " ==> before")
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
;FileWriteLine("debug.log",@min & ":" & @sec & " ==> after")
WEnd
EndFunc ;==>_Main
;
Func Timer()
_TicksToTime(Int(TimerDiff($timer)), $Hour, $Mins, $Secs)
Local $sTime = $Time ; 調べて誤差を除けるように現在時刻を保存
$Time = StringFormat("%02i:%02i:%02i", $Hour, $Mins, $Secs)
If $sTime <> $Time Then ControlSetText("Timer", "", "Static1", $Time)
EndFunc ;==>Timer