指定されたウィンドウを点滅します。
#Include <WinAPI.au3>
_WinAPI_FlashWindowEx($hWnd [, $iFlags = 3 [, $iCount = 3 [, $iTimeout = 0]]])
パラメータ
| $hWnd | 点滅されるウィンドウのハンドル。ウィンドウは開かれているか、最小化されているかのどちらかです。 |
| $iFlags | [オプション]点滅状態。次の値の1つまたは複数です: 0 - 点滅を停止します。システムはウィンドウを元の状態に戻します。 1 - ウィンドウのキャプション点滅します 2 - タスクバーのボタンを点滅します 4 - 停止されるまで点滅を続けます 8 - ウィンドウが最前面に来るまで点滅を続けます |
| $iCount | [オプション]ウィンドウを点滅させる回数 |
| $iTimeout | [オプション]ウィンドウが点滅させられるミリ秒単位での間隔。 0の場合、この関数はデフォルトのカーソル点滅間隔を使用します。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
通常は現在キーボードフォーカスが合っておらず、なおかつ注意を喚起する必要のあるウィンドウを
関連
_WinAPI_FlashWindow
こちらも参照
MSDNライブラリでFlashWindowExを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hwnd, $Flash, $Timeout, $btnFlash, $msg, $flashrate, $timeoutrate, $flashing = False
$hwnd = GUICreate("Form1", 229, 170, 193, 125)
$Flash = GUICtrlCreateInput("20", 80, 72, 121, 21)
$Timeout = GUICtrlCreateInput("500", 80, 103, 121, 21)
GUICtrlCreateLabel("Please input the flash rate, and the time between flashes", 8, 24, 214, 41)
GUICtrlCreateLabel("Flash Rate:", 16, 72, 58, 17)
GUICtrlCreateLabel("Timeout (ms)", 16, 104, 64, 17)
$btnFlash = GUICtrlCreateButton("Flash Window", 80, 136, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion
While 1
$msg = GUIGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
Exit
Case $btnFlash
If $flashing Then
_WinAPI_FlashWindowEx($hwnd, 0)
$flashing = False
Else
$flashrate = GUICtrlRead($Flash)
$timeoutrate = GUICtrlRead($Timeout)
_WinAPI_FlashWindowEx($hwnd, 2, $flashrate, $timeoutrate)
GUICtrlSetData($btnFlash, "Stop Flashing")
$flashing = True
EndIf
EndSwitch
WEnd
EndFunc ;==>_Main