指定されたモジュールに関連付けられた実行ファイルから文字列リソースをロードします。
#Include <WinAPI.au3>
_WinAPI_LoadString($hInstance, $iStringId)
パラメータ
| $hInstance | 実行ファイルに文字列リソースを格納しているモジュールのインスタンスのハンドル |
| $iStringId | ロードされる文字列の整数の識別子を指定します |
返し値
| 成功: | 要求された文字列。@extendedはコピーされたTCHARS数です。 |
| 失敗: | 空文字列。@errorが設定されます。 |
注意
なし。
関連
_WinAPI_LoadLibraryEx, _WinAPI_FreeLibrary
こちらも参照
MSDNライブラリでLoadStringを検索して下さい。
例
#include <GuiReBar.au3>
#include <WinAPI.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hInput, $btn_get, $hReBar, $hInstance, $sText
; GUI作成
$hGUI = GUICreate("WinAPI", 400, 396)
$hInput = GUICtrlCreateInput("4209", 0, 0, 100, 20)
; リバーコントロールを作成
$hReBar = _GUICtrlReBar_Create($hGUI, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))
$iMemo = GUICtrlCreateEdit("", 2, 55, 396, 200, BitOR($WS_VSCROLL, $WS_HSCROLL))
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
; コントロールを格納したバンドを追加
_GUICtrlReBar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "String ID:")
$btn_get = GUICtrlCreateButton("Get String", 0, 0, 90, 20)
; コントロールを格納したバンドを追加
_GUICtrlReBar_AddBand($hReBar, GUICtrlGetHandle($btn_get), 120, 200)
GUISetState()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $btn_get
GUICtrlSetData($iMemo, "")
$hInstance = _WinAPI_LoadLibraryEx("shell32.dll", $LOAD_LIBRARY_AS_DATAFILE)
If $hInstance Then
$sText = _WinAPI_LoadString($hInstance, GUICtrlRead($hInput))
If Not @error Then
MemoWrite('Got the String (chars: ' & @extended & '): ' & @CRLF & $sText)
Else
MemoWrite("Last Error Message: " & @CRLF & _WinAPI_GetLastErrorMessage())
EndIf
MemoWrite(@CRLF & "Success Freeing? " & _WinAPI_FreeLibrary($hInstance))
EndIf
EndSwitch
WEnd
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite