TreeView32コントロールにコマンドを送信します。
ControlTreeView ( "title", "text", controlID, "command" [, option1 [, option2]] )
パラメータ
| title | アクセスするウィンドウのタイトル |
| text | アクセスするウィンドウのテキスト |
| controlID | 操作するコントロール。Controlsを参照。 |
| command | コントロールに送信するコマンド（下記を参照）。 |
| option1 | [オプション] コマンドに依存して要求される追加パラメータ |
| option2 | [オプション] コマンドに依存して要求される追加パラメータ |
返し値
下の表に示すコマンドに依存します。エラー（無効なコマンド、ウィンドウ/コントロールが見つからないなど）の場合には@errorを1に設定します。| コマンド、オプション1、オプション2 | 動作 |
| "Check", "item" | (アイテムがサポートしている場合) アイテムをチェックします。 |
| "Collapse", "item" | アイテムをたたんで子アイテムを非表示にします。 |
| "Exists", "item" | アイテムが存在する場合、1を返します。それ以外の場合は0。 |
| "Expand", "item" | アイテムを展開して子アイテムを表示します。 |
| "GetItemCount", "item" | 選択されたアイテムの子アイテムの数を返します。 |
| "GetSelected" [, UseIndex] | アイテムのテキスト（UseIndexが1の場合はインデックス）を使って現在選択されているアイテムの参照を返します。 |
| "GetText", "item" | アイテムのテキストを返します。 |
| "IsChecked" | アイテムの状態を返します。1:チェックされている、0:チェックされていない、-1:チェックボックスではない |
| "Select", "item" | アイテムを選択します。 |
| "Uncheck", "item" | （アイテムがサポートしている場合）アイテムを非選択にします。 |
| アイテム | アイテムの参照 |
| Heading2 | "Heading2" または "#1" |
| H1SubItem2 | "Heading1|H1SubItem2" または "#0|#1" |
| H1S1SubItem1 | "Heading1|H1SubItem3|H1S1SubItem1" または "#0|#2|#0" |
注意
AutoItは32ビットアプリケーションなので64ビットWindowsで実行する場合、エクスプローラなどの64ビットアプリケーションを参照するときに使用できないコマンドがいくつかあります。
関連
ControlCommand
例
; 作成者: Zedna
#include <GUIConstantsEx.au3>
#include <TreeviewConstants.au3>
#include <WindowsConstants.au3>
$gui = GUICreate("ControlTreeview test", 212, 212)
$treeview = GUICtrlCreateTreeView(6, 6, 200, 160, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
$h_tree = ControlGetHandle($gui, "", $treeview)
$root = GUICtrlCreateTreeViewItem("Root", $treeview)
$item1 = GUICtrlCreateTreeViewItem("Item 1", $root)
$item2 = GUICtrlCreateTreeViewItem("Item 2", $root)
$item3 = GUICtrlCreateTreeViewItem("Item 3", $root)
$item4 = GUICtrlCreateTreeViewItem("Item 4", $root)
$item41 = GUICtrlCreateTreeViewItem("Item 41", $item4)
$item42 = GUICtrlCreateTreeViewItem("Item 42", $item4)
$item5 = GUICtrlCreateTreeViewItem("Item 5", $root)
GUISetState(@SW_SHOW)
; いくつかの例
ControlTreeView ($gui, "", $h_tree, "Expand", "Root")
ControlTreeView ($gui, "", $h_tree, "Exists", "Root|Item 4")
ControlTreeView ($gui, "", $h_tree, "Check", "Root|Item 4")
ControlTreeView ($gui, "", $h_tree, "Select", "Root|Item 4")
ControlTreeView ($gui, "", $h_tree, "Expand", "Root|Item 4")
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
EndSelect
WEnd