GUI用のメニューアイテムコントロールを作成します。
GUICtrlCreateMenuItem ( "text", menuID [, menuentry [, menuradioitem]] )
パラメータ
| text | コントロールのテキスト。 |
| menuID | 定義した場合、指定したメニューにサブメニューを作成することができます。-1を指定すると 最初のレベルのメニューが指定されます。 |
| menuentry | [オプション] 作成するエントリーに番号を定義することができます。エントリー番号は0始まりです。 |
| menuradioitem | [オプション] 0 (デフォルト) = 通常のメニューアイテム作成、 1 = メニューラジオアイテムを作成 |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
コントロールの情報を設定/変更する方法についてはGUICtrlUpdate...を参照。
関連
GUICtrlUpdate..., GUIGetMsg, GUICtrlCreateMenu, GUICtrlCreateContextMenu
例
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $defaultstatus, $status, $filemenu, $fileitem, $helpmenu, $saveitem
Local $infoitem, $exititem, $recentfilesmenu, $separator1, $viewmenu
Local $viewstatusitem, $okbutton, $cancelbutton, $statuslabel, $msg, $file
GUICreate("My GUI menu", 300, 200)
Global $defaultstatus = "Ready"
Global $status
$filemenu = GUICtrlCreateMenu("&File")
$fileitem = GUICtrlCreateMenuItem("Open", $filemenu)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$helpmenu = GUICtrlCreateMenu("?")
$saveitem = GUICtrlCreateMenuItem("Save", $filemenu)
GUICtrlSetState(-1, $GUI_DISABLE)
$infoitem = GUICtrlCreateMenuItem("Info", $helpmenu)
$exititem = GUICtrlCreateMenuItem("Exit", $filemenu)
$recentfilesmenu = GUICtrlCreateMenu("Recent Files", $filemenu, 1)
$separator1 = GUICtrlCreateMenuItem("", $filemenu, 2) ; セパレートライン作成
$viewmenu = GUICtrlCreateMenu("View", -1, 1) ; "?"メニューの前に作成される
$viewstatusitem = GUICtrlCreateMenuItem("Statusbar", $viewmenu)
GUICtrlSetState(-1, $GUI_CHECKED)
$okbutton = GUICtrlCreateButton("OK", 50, 130, 70, 20)
GUICtrlSetState(-1, $GUI_FOCUS)
$cancelbutton = GUICtrlCreateButton("Cancel", 180, 130, 70, 20)
$statuslabel = GUICtrlCreateLabel($defaultstatus, 0, 165, 300, 16, BitOR($SS_SIMPLE, $SS_SUNKEN))
GUISetState()
While 1
$msg = GUIGetMsg()
If $msg = $fileitem Then
$file = FileOpenDialog("Choose file...", @TempDir, "All (*.*)")
If @error <> 1 Then GUICtrlCreateMenuItem($file, $recentfilesmenu)
EndIf
If $msg = $viewstatusitem Then
If BitAND(GUICtrlRead($viewstatusitem), $GUI_CHECKED) = $GUI_CHECKED Then
GUICtrlSetState($viewstatusitem, $GUI_UNCHECKED)
GUICtrlSetState($statuslabel, $GUI_HIDE)
Else
GUICtrlSetState($viewstatusitem, $GUI_CHECKED)
GUICtrlSetState($statuslabel, $GUI_SHOW)
EndIf
EndIf
If $msg = $GUI_EVENT_CLOSE Or $msg = $cancelbutton Or $msg = $exititem Then ExitLoop
If $msg = $infoitem Then MsgBox(0, "Info", "Only a test...")
WEnd
GUIDelete()
EndFunc ;==>Example