Function Reference

TrayItemGetHandle

トレイメニュー(アイテム)のハンドルを返します。

TrayItemGetHandle ( controlID )

 

パラメータ

controlID TrayCreateItemTrayCreateMenuによって返されるコントロール識別子(コントロールID)

 

返し値

成功 指定されたコントロールIDのハンドルを返します。
失敗 0を返します。

 

注意

トレイコンテキストメニュー自体のハンドルを取得する場合はコントロールIDとして'0'を指定してください。

 

関連

TrayItemGetState, TrayItemGetText

 


#include <Constants.au3>

Opt("TrayMenuMode", 1) ; デフォルトのトレイコンテキストメニューを非表示

Global Const $MIM_APPLYTOSUBMENUS   = 0x80000000
Global Const $MIM_BACKGROUND        = 0x00000002

TraySetIcon("shell32.dll", 21)
TraySetToolTip("This is just a small example to show that colored tray menus" & @LF & "are easy possible under Windows 2000 and higher.")

$OptionsMenu    = TrayCreateMenu("Options")
$OnTopItem      = TrayCreateItem("Always On Top", $OptionsMenu)
TrayItemSetState(-1, $TRAY_CHECKED)
$RepeatItem     = TrayCreateItem("Repeat Always", $OptionsMenu)
TrayCreateItem("")
$AboutItem      = TrayCreateItem("About")
TrayCreateItem("")
$ExitItem       = TrayCreateItem("Exit Sample")

SetMenuColor(0, 0xEEBB99)   ; BGRカラー値 '0' はコンテキストメニューハンドルを表す
SetMenuColor($OptionsMenu, 0x66BB99); BGRカラー値

While 1
    $Msg = TrayGetMsg()

    Switch $Msg
        Case $ExitItem
            ExitLoop
        
        Case $AboutItem
            Msgbox(64, "About...", "Colored tray menu sample")
    EndSwitch   
WEnd

Exit


; 色をメニューに適用
Func SetMenuColor($nMenuID, $nColor)
    $hMenu  = TrayItemGetHandle($nMenuID) ; 内部メニューハンドルを取得
   
    $hBrush = DllCall("gdi32.dll", "hwnd", "CreateSolidBrush", "int", $nColor)
    $hBrush = $hBrush[0]
        
    Local $stMenuInfo = DllStructCreate("dword;dword;dword;uint;dword;dword;ptr")
    DllStructSetData($stMenuInfo, 1, DllStructGetSize($stMenuInfo))
    DllStructSetData($stMenuInfo, 2, BitOr($MIM_APPLYTOSUBMENUS, $MIM_BACKGROUND))
    DllStructSetData($stMenuInfo, 5, $hBrush)
   
    DllCall("user32.dll", "int", "SetMenuInfo", "hwnd", $hMenu, "ptr", DllStructGetPtr($stMenuInfo))
EndFunc